Advent of Ada Submissions

JeremyGrosser · December 4, 2022, 5:15am

[JeremyGrosser][4][Ada][advent/day4_2.adb at 3886b077597131c55f15bd23bf3f5dc14faeb4c8 · JeremyGrosser/advent · GitHub]

zertovitch · December 4, 2022, 5:56am

[Zertovitch][4][Ada]hac/aoc_2022_04.adb at 74dd26dbb513dec406561fa5e8cc439f6abe802c · zertovitch/hac · GitHub

rocher · December 4, 2022, 6:41am

[rocher][4][Ada] Part one here:

pragma Ada_2022;

with Ada.Text_IO;         use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Day04_P1 is

    type Section_Range is record
        Start_Section : Natural := 0;
        End_Section   : Natural := 0;
    end record;

    function Contains (A, B : Section_Range) return Boolean is
       (A.Start_Section >= B.Start_Section
        and then A.End_Section <= B.End_Section);
    -- returns True when A contains B: B ⊆ A

    First, Second : Section_Range;
    Separator     : Character;
    Σ_Contained   : Natural := 0;
    Input         : File_Type;

begin
    Open (Input, In_File, "input.txt");

    loop
        Get (Input, First.Start_Section);
        Get (Input, Separator); -- skip '-'
        Get (Input, First.End_Section);

        Get (Input, Separator); -- skip ','

        Get (Input, Second.Start_Section);
        Get (Input, Separator); -- skip '-'
        Get (Input, Second.End_Section);

        if Contains (First, Second) or else Contains (Second, First) then
            Σ_Contained := @ + 1;
        end if;

        exit when End_Of_File (Input);
    end loop;

    Close (Input);
    Put_Line ("Answer:" & Σ_Contained'Image);
end Day04_P1;

and part 2:

pragma Ada_2022;

with Ada.Text_IO;         use Ada.Text_IO;
with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;

procedure Day04_P2 is

    type Section_Range is record
        Start_Section : Natural := 0;
        End_Section   : Natural := 0;
    end record;

    function Disjoint (A, B : Section_Range) return Boolean is
       (A.End_Section < B.Start_Section
        or else B.End_Section < A.Start_Section);
    -- returns True when sections are like --AA-BB- or --BB-AA--
    -- that is: A ∩ B = ∅

    First, Second : Section_Range;
    Separator     : Character;
    Σ_Overlap     : Natural := 0;
    Input         : File_Type;

begin
    Open (Input, In_File, "input.txt");

    loop
        Get (Input, First.Start_Section);
        Get (Input, Separator); -- skip '-'
        Get (Input, First.End_Section);

        Get (Input, Separator); -- skip ','

        Get (Input, Second.Start_Section);
        Get (Input, Separator); -- skip '-'
        Get (Input, Second.End_Section);

        if not Disjoint (First, Second) then
            Σ_Overlap := @ + 1;
        end if;

        exit when End_Of_File (Input);
    end loop;

    Close (Input);
    Put_Line ("Answer:" & Σ_Overlap'Image);
end Day04_P2;

cantanima · December 4, 2022, 7:32am

[cantanima][4][SPARK]Solved this one in Ada, then “converted” to SPARK

rvlad13 · December 4, 2022, 9:26am

[rvlad13][1][Ada] GitHub - rvl13/Advent_of_code_2022_Ada
[rvlad13][2][Ada] same repo
[rvlad13][3][Ada] same repo
[rvlad13][4][Ada] same repo

Since I am new user, it doesn’t allow me to post more than 2 links, So not able to put link to all the solutions. Anyways, all the solutions are located in same repo.
I have also started making use of HAC Ada Compiler today (day 4) onwards.